Compute VM Instance with a Static_IP

Google Cloud Compute Infrastructure
1

Q:- To create a gcp compute VM with a network, subnetwork and a static_IP.

I’m trying to create a GCP VM instance with a reserved IP address through Terraform modules. Initially, I created a google_compute_address resource with a static IP. Now, how do I pass this reserved static IP address (from google_compute_address) to the compute VM Terraform configuration? Which additional variables would help in this use case? Please suggest any helpful references or resources related to this use case.

2

Which Terraform modules are you using to create the VM? A simple guideline you can follow is to reference one resource block to another in Terraform. In your case, it would look something like this (as shown in the Terraform documentation example) -

resource "google_compute_address" "static" {
  name = "ipv4-address"
}

data "google_compute_image" "debian_image" {
  family  = "debian-11"
  project = "debian-cloud"
}

resource "google_compute_instance" "instance_with_ip" {
  name         = "vm-instance"
  machine_type = "f1-micro"
  zone         = "us-central1-a"

  boot_disk {
    initialize_params {
      image = data.google_compute_image.debian_image.self_link
    }
  }

  network_interface {
    network = "default"
    access_config {
      nat_ip = google_compute_address.static.address
    }
  }
}
1 Like
3

Hi @Dg03cloud

Welcome to Google Cloud Community!

I agree with @mokit that the provided configuration will create a resource address and assign the created static IP address to the VM. However, the configuration was intended to output an Ephemeral External IP address. An example of how to create and attach a Reserved Internal IP static address to a VM is provided in the configuration below.

In response to your query, here are the variables or attributes that you need to configure:

/Block Interface for google compute instance
network_interface {
    network = "xxxxxx" # Name of your VPC network
    subnetwork = "xxxxx" #Name of your Subnetwork on your VPC
    network_ip = google_compute_address.Internalstatic(Root ID).address      
#Alternatively, you can specify an IP address; e.g., 10.0.0.8
  }
 }

Example of Reserved Internal Static IP address Configuration:

#Creating Reserved Internal IP address 
resource "google_compute_network" "vpc-static" {
  name = "my-network"
  auto_create_subnetworks = false #Set true to auto_subnet mode
}

resource "google_compute_subnetwork" "vpc-subnet-static" {
  name          = "my-subnet"
  ip_cidr_range = "x.x.x.x/x"
  region        = "us-central1"
  network       = google_compute_network.vpc-static.id
}

resource "google_compute_address" "Internalstatic" {
  name   = "static-ip-address"
  address_type  = "INTERNAL"
  region = "us-central1"
  subnetwork   = google_compute_subnetwork.vpc-subnet-static.id
  address = "x.x.x.x"
}

resource "google_compute_instance" "VMwithStaticIP" {
  name         = "test-vm5"
  machine_type = "n1-standard-1"
  zone         = "us-central1-a"

  boot_disk {
    initialize_params {
      image = "debian-cloud/debian-11"
    }
  }

  network_interface {
    network = "my-network"
    subnetwork = "my-subnet"
    network_ip = google_compute_address.Internalstatic.address
  }
 }

As a result, here is the created Reserved Internal Static IP address:

image (4).png
image (4).png1432×131 13.2 KB

For more information, see the relevant documentation and codes template that may help you:

To get information about Address:

Terraform Google Provider Documentation:

Terraform Basics:

Google Cloud Documentation:

Was this helpful? If so, please accept this answer as “Solution”. If you need additional assistance, reply here within 2 business days and I’ll be happy to help.

3 Likes
4

Thank you for your prompt reply. I was able to create a VM instance with an assigned private IP.

1 Like
5

@reinc Thank you. I was able to create a VM instance with a static private IP.

1 Like